10 REM FLYING BOMB
20 REM  MICHAEL BEWS
30 GOSUB 630
40 MODE 1:BORDER 1:INK 0,0:INK 1,24:INK 2,20:INK 3,6:WINDOW #1,1,40,1,25:PAPER #1,0:CLS #1
50 SC=0
60 PO=0:CR=0:DIST=270000:DC=DIST:TH=1000:D=0:H=4:DK=D:HK=H:S=150
70 WINDOW #0,5,36,1,25:PAPER #0,0:PEN #1,1:CLS #0
80 PEN 3:PAPER 0:PRINT CHR$(24);" FLYING BOMB ";CHR$(24);:PEN 1
90 LOCATE 1,3:PEN 2:PRINT "SCORE:":PEN 3:LOCATE 7,3:PRINT SC:PEN 1
100 LOCATE 14,1:PRINT "MLS TO TARGET":LOCATE 18,2:PEN 3:PRINT "HEIGHT FT":LOCATE 18,3:PEN 2:PRINT "SPEED NTS":PEN 1
110 LOCATE 1,19:PRINT STRING$(32," ")
120 LOCATE 1,22:PEN 3:PRINT CHR$(24);"UP & DOWN CURSOR KEYS FOR HEIGHTLEFT AND RIGHT FOR SPEED AND THECOPY KEY TO RELEASE BOMB!       ";CHR$(24):PEN 1
130 LOCATE 32,15:PRINT CHR$(235);:LOCATE 31,16:PRINT CHR$(236);CHR$(143);:LOCATE 30,17:PRINT CHR$(236);CHR$(143);CHR$(143);:LOCATE 29,18:PRINT CHR$(236);CHR$(143);CHR$(143);CHR$(143);
140 REM *** MAIN ROUTINE ***
150 LOCATE 28,2:PRINT "    ":LOCATE 27,2:PEN 2:PRINT INT((17-H)*100-20):PEN 1
160 PEN 3:LOCATE 28,1:PRINT "     ":LOCATE 27,1:PRINT (27-D)/5:PEN 1
170 LOCATE 28,3:PRINT "    ":LOCATE 27,3:PEN 3:PRINT S*2:PEN 1
180 LOCATE DK+1,HK+1:PRINT "  ":LOCATE D+1,H+1:PRINT CHR$(231);CHR$(232);:HK=H:DK=D
190 IF INKEY$="" THEN 260
200 IF INKEY(1)=0 THEN S=S+5:IF S>195 THEN S=195
210 IF INKEY(8)=0 THEN S=S-5:IF S<45 THEN LOCATE 12,17:PRINT CHR$(24);"STALLED!";CHR$(24):GOTO 580
220 IF INKEY(0)=0 THEN H=H-0.1
230 IF INKEY(2)=0 THEN H=H+0.1:IF H>16.8 THEN 500
240 IF H<2.2 THEN H=2.2
250 IF INKEY(9)=0 THEN LOCATE DK+1,HK+1:PRINT CHR$(231);CHR$(233);:GOTO 310
260 IF H>13 AND D>27 THEN 520
270 REM *** MOVE CLOSER ***
280 DC=DC-S:D=INT((DIST-DC)/TH)
290 IF D>30 THEN GOTO 540
300 GOTO 140
310 REM *** BOMB DROPPED ***
320 Y=1:V=H+1:F=D+1:HK=V:DK=F
330 X=Y*Y*(1-S/200)
340 SOUND 1,120,4
350 V=V+X/40:F=F+Y/8
360 IF V>15 AND F<28 THEN 430
370 IF V>18.5 OR F>31 THEN 540
380 LOCATE DK+1,HK+1:PRINT " ";
390 LOCATE F+1,V+1:PRINT CHR$(234)
400 HK=V:DK=F
410 Y=Y+1:GOTO 330
420 REM *** WON GAME ***
430 LOCATE DK+1,HK+1:PRINT " ";
440 LOCATE 12,17:PEN 2:PRINT "CONGRATULATIONS!":PEN 1
450 SC=SC+1:LOCATE 7,3:PEN 3:PRINT SC
460 LOCATE 32,15:PRINT " ";:LOCATE 31,16:PRINT "  ";:LOCATE 30,17:PRINT "   ";:LOCATE 29,18:PRINT "    "
470 FOR X=-10 TO 10:SOUND 1,(X+100),4:NEXT
480 FOR X=1 TO 1000:NEXT:RESTORE:GOTO 60
490 REM *** DITCHED ***
500 LOCATE 12,17:PEN 2:PRINT CHR$(24);"DITCHED!";CHR$(24);:PEN 1:GOTO 590
510 REM *** CRASH ON TARGET ***
520 LOCATE 12,17:PRINT "  ":GOTO 460
530 REM *** LOST GAME ***
540 LOCATE DK+1,HK+1:PRINT "  "
550 LOCATE 12,17:PEN 3:PRINT " LOST! ":PEN 1
560 GOTO 590
570 REM *** STALLED ***
580 FOR X=H TO 17:LOCATE D+1,X+1:PRINT "  ";:LOCATE D+1,X+2:PRINT CHR$(231);CHR$(232):NEXT
590 FOR X=-10 TO 10:SOUND 1,(X+150),4:NEXT
600 FOR X=1 TO 1000:NEXT
610 RESTORE:GOTO 60
620 STOP
630 SYMBOL AFTER 230
640 SYMBOL 231,192,64,127,26,15,0,0,0
650 SYMBOL 232,0,0,248,175,254,190,127,190
660 SYMBOL 233,0,0,248,175,254,0,0,0
670 SYMBOL 234,0,0,0,0,0,190,127,190
680 SYMBOL 235,64,64,64,64,64,64,64,255
690 SYMBOL 236,1,3,7,15,31,63,127,255
700 RETURN