10 'DISCUT - Utilitaire pour DISC AMSTRAD
20 'Michel Archambault 9/1985
50 CLS
100 PRINT "Cat  Erase  Rename  Drive  Quitter ? "
110 Q$="":WHILE Q$="":Q$=UPPER$(INKEY$):WEND
120 Q=INSTR("CERDQ",Q$):IF Q=0 THEN 110
130 ON Q GOSUB 200,300,400,500,600
140 GOTO 100
200 CAT:RETURN
300 INPUT "  ERASER quel Fichier ? ",F$:GOSUB 1000:IF REFUS THEN 390
320 IF F$="*.*" THEN PRINT"  Etes-vous bien sur ?...(O/N) ";:R$="":WHILE R$="":R$=UPPER$(INKEY$):WEND:IF R$="N" THEN 390 ELSE IF R$<>"O" THEN 320
330 ERA,F$
390 RETURN
400 INPUT "  ANCIEN NOM : ",F$:IF INSTR(F$,"*") >0 THEN 400
410 GOSUB 1000:IF REFUS THEN 490 ELSE A$=F$
420 INPUT " NOUVEAU NOM : ",F$:IF INSTR(F$,"*") >0 THEN 420
430 GOSUB 1000:IF REFUS THEN 490 ELSE N$=F$
440 REN,N$,A$
490 RETURN
500 PRINT "  SUR QUEL DRIVE (A/B) ?"
510 D$="":WHILE D$="":D$=UPPER$(INKEY$):WEND
520 IF D$<>"A" AND D$<>"B" THEN 510
530 DRIVE,D$
590 RETURN
600 END
1000 'SECURITE DU NOM DE FICHIER
1010 L=LEN(F$):REFUS=0
1020 IF INSTR(F$,CHR$(32)) >0 OR L=0 THEN REFUS=1
1030 P=INSTR(F$,".")
1040 IF P>9 OR (P=0 AND L>8) THEN REFUS=1
1050 IF P>0 AND L-P>3 THEN REFUS=1
1090 IF REFUS THEN PRINT CHR$(7);
1100 RETURN
HEN PRINT CHR$(7);
1100 RETURN