retry call MOTORON_DELAY
    jr nc,retry
    ld a,3
    ld bc,#cc0
    call ReadTrack ; from track 3 read 12 tracks in #C000 => #8000
    jr nc,retry
    ld bc,#bc01
    ld hl,#2a
    call SetCRTC
    call MOTORON_DELAY
    jr nc,retry
    ld sp,#4000
    ld a,15
    ld bc,#480
    call ReadTrack ; from track 15 read 4 tracks in #8000
    jr nc,retry
    call MOTORON_DELAY
    jr nc,retry
    ld sp,labBFFF+1
    ld a,19
    ld bc,#4c0
    call ReadTrack ; from track 19 read 4 tracks in #C000
    jr nc,retry

    ld bc,#bc01
    ld hl,#202a
    call SetCRTC ; set screen
    ld c,6
    ld hl,#181d
    call SetCRTC
    ld b,127
    xor a
    ld hl,labBF98
.loop ld c,(hl)
    out (c),a
    out (c),c
    inc l
    inc a
    and 3
    jr nz,.loop
    rst 0

SetCRTC out (c),c
    inc b
    out (c),h
    dec b
    inc c
    out (c),c
    inc b
    out (c),l
    dec b
    ret

;
; si on n'arrive pas à avoir le READY et une disquette déprotégée après un (re)démarrage moteur,
; on coupe et on revient au tout tout début du loader
; Sinon, ben on coupe le moteur quand même oO
;
MOTORON_DELAY call MotorON ; BE6D
    ld hl,#C000
.rewait ld b,3
.wait djnz .wait
    dec hl
    ld a,h
    or l
    jr nz,.rewait

    ld bc,#fb7f
    call GetET3_02
    inc a
    jr z,MotorOFF
    call MakeCalibration
    scf
    jp labBE8D ; couper le moteur WTF ???

; motorOFF
MotorOFF and a
labBE8D push af
    ld bc,#fa7e
    xor a
    out (c),a
    pop af
    ret

MakeCalibration_01 call FDCIsReady
    ld a,7
    call PutFDC
    xor a
    out (c),a
    ld l,255
.get_ET3_loop call FDCIsReady
    ld a,4
    call PutFDC
    xor a
    call PutFDC
    in a,(c)
    and 16
    jp nz,FDCIsReady
    dec l
    jr nz,.get_ET3_loop
    jr MakeCalibration_01

MotorON ld bc,#fa7e ; BEBB
    ld a,1
    out (c),a
    ret

PutFDC  out (c),a ; BEC3
FDCIsReady dec c  ; BEC5
.ready in a,(c)
    rla
    jr nc,.ready
    inc c
    ret

GetET3_02 ld a,4    ; BECD
    call PutFDC
    xor a
    call PutFDC
    in a,(c)
    ld l,a
    and 32
    jr z,labBEE7
    ld a,l
    and 64
    jr nz,labBEEA
    call FDCIsReady
    xor a        ; ready + protected
    ret
labBEE7 ld a,255 ; not ready
    ret
labBEEA ld a,254 ; protected
    ret

SetVar ld (track),a
    ld h,c
    ld l,0
    ld (destination),hl
    ret

ReadTrack call SetVar ; préparation des variables, piste, destination, compteurs
    push bc
    call MotorON ; on rallume ce qu'on vient d'éteindre...
    ld bc,#fb7f
    call GetET3_02 ; statut du lecteur
    inc a
    jp z,MotorOFF ; pas ready tu coupes et tu te casses???

    call SeekTrack
    call ReadSector
    pop bc
    ld a,c
    add a,16 ; avance de 4K dans la RAM pour la destination
    ld c,a
    ld a,(track)
    inc a
    djnz ReadTrack ; on incrémente la piste autant de fois que requis
    scf ; flag OK
    ret

SeekTrack call FDCIsReady
    ld a,15
    call PutFDC
    xor a
    call PutFDC
    ld a,(track)
    call PutFDC
; Sense FDC Int
    ld a,8
    call PutFDC
    in l,(c)
    call FDCIsReady
    in a,(c)
    ld a,l
    and 192 ; DEGUEULASSE, on considère OK une erreur de calibration ou un lecteur eteint...
    jp z,FDCIsReady
    jr SeekTrack ; DEGUEULASSE !!!!! On ne devrait reboucler que sur le SensInterrupt (et encore, autrement)


ReadSector ld de,#4007
    call FDCIsReady
    ld a,70
    call PutFDC
    call ReadParam
    ld a,128
    out (c),a ; dernier parametre de la commande ReadSector...
    dec c
.ready in a,(c)
    rla
    jr nc,.ready
    and d
    jr z,GetResult
    inc c
    in a,(c)
    ld (hl),a
    inc hl
    dec c
    jr .ready

GetResult inc c
.loop in a,(c)
    dec e
    jp z,FDCIsReady
    call FDCIsReady
    jr .loop

ReadParam xor a
    call PutFDC
    ld a,0 : track EQU $-1
    call PutFDC
    xor a
    call PutFDC
    ld a,1
    call PutFDC
    ld a,2
    call PutFDC
    ld a,8
    call PutFDC
    ld a,42
    ld hl,#0 : destination EQU $-1
    jp PutFDC

    ld c,e
    ld d,h
    ld c,d
    ld d,a

labBF98 ld d,h
    ld c,d
    ld d,a
labBF9B ld d,(hl)