typedef struct
{
   unsigned char x, y;
   unsigned char* pData;
}
tSprite8x16;


void sprite_8x16_draw(tSprite8x16* pSprite)
{
   __asm
   ;; load IX with sprite information
   ld   l,4 (ix)
   ld   h,5 (ix)
   push hl
   pop ix

   ; calculate sprite screen adress in hl
   ld   hl,#_aScreenLinesOffset
   ld   e,1(ix)
   ld   d,#0
   rl   d
   rl   e
   add   hl,de
   ld   a,(hl)
   ld   e,a
   inc   hl
   ld   a,(hl)
   ld   d,a
   push de
   pop   hl
   ld e,0(ix)
   ld d,#0
   add hl,de

   ; load de with adress to sprite data
   ld e,2(ix)
   ld d,3(ix)

   ld   bc,#0x0208
sprite_draw_loop:
sprite_next_pixel_0:
   ld   a,(de)
   inc de
   or   a
   jp   z, sprite_next_pixel_1
   ld   (hl),a
sprite_next_pixel_1:
   inc hl
   ld   a,(de)
   inc de
   or   a
   jp   z, sprite_next_pixel_2
   ld   (hl),a
sprite_next_pixel_2:
   inc hl
   ld   a,(de)
   inc de
   or   a
   jp   z, sprite_next_pixel_3
   ld   (hl),a
sprite_next_pixel_3:
   inc hl
   ld   a,(de)
   inc de
   or   a
   jp   z, sprite_next_row
   ld   (hl),a
sprite_next_row:
   ld   a,l
   add   #0xfd
   ld   l,a
   ld   a,h
   adc #0x7
   ld   h,a
   dec   c
   jp   nz,sprite_draw_loop
   ld   c,#0x08
   ld   a,l
   add   #0x40
   ld   l,a
   ld   a,h
   adc #0xc0
   ld   h,a
   dec   b
   jp nz,sprite_draw_loop

   __endasm;
}

void sprite_8x16_mask_draw(tSprite8x16* pSprite)
{
   __asm
   ;; load IX with sprite information
   ld   l,4 (ix)
   ld   h,5 (ix)
   push hl
   pop ix

   ; calculate sprite screen adress in hl
   ld   hl,#_aScreenLinesOffset
   ld   e,1(ix)
   ld   d,#0
   rl   d
   rl   e
   add   hl,de
   ld   a,(hl)
   ld   e,a
   inc   hl
   ld   a,(hl)
   ld   d,a
   push de
   pop   hl
   ld e,0(ix)
   ld d,#0
   add hl,de

   ; load de with adress to sprite data
   ld e,2(ix)
   ld d,3(ix)

   ld   bc,#0x0208
sprite_draw_mask_loop:
   ;;
   ld a,(de)
   and (hl)
   inc de
   ld (hl),a
   ld a,(de)
   or (hl)
   inc de
   ld (hl),a
   inc hl
   ;;
   ld a,(de)
   and (hl)
   inc de
   ld (hl),a
   ld a,(de)
   or (hl)
   inc de
   ld (hl),a
   inc hl
   ;;
   ld a,(de)
   and (hl)
   inc de
   ld (hl),a
   ld a,(de)
   or (hl)
   inc de
   ld (hl),a
   inc hl
   ;;
   ld a,(de)
   and (hl)
   inc de
   ld (hl),a
   ld a,(de)
   or (hl)
   inc de
   ld (hl),a

   ld   a,l
   add   #0xfd
   ld   l,a
   ld   a,h
   adc #0x7
   ld   h,a
   dec   c
   jp   nz,sprite_draw_mask_loop
   ld   c,#0x08
   ld   a,l
   add   #0x40
   ld   l,a
   ld   a,h
   adc #0xc0
   ld   h,a
   dec   b
   jp nz,sprite_draw_mask_loop
   __endasm;
}