CPC Rulez
https://cpcrulez.fr/forum/

ELITE
https://cpcrulez.fr/forum/viewtopic.php?f=10&t=3022
Page 1 sur 1

Auteur :  Princesse Mariana [ 08 Jan 2009, 20:26 ]
Sujet du message :  ELITE

POKE(S) pour le jeu AMSTRAD CPC "ELITE"

INFINITE FUEL : POKE &7401,&00
INFINITE MISSILES : POKE &4611,&00


Auteur :  Princesse Mariana [ 09 Jan 2009, 20:26 ]
Sujet du message :  ELITE

Code :
10 :' Elite - disk
20 :'Thanks to Adrian Forbes
30 :'
40 MODE 1:BORDER 0:INK 0,0
47 ùUSER,0
50 INK 1,24:INK 2,15:INK 3,6
60 WINDOW #1,14,26,12,12
70 WINDOW #2,14,26,12,14
80 LOAD"common2x",&C000
90 OPENOUT"d"
100 MEMORY &83F
110 CLOSEOUT
120 LOAD"largeaxx",&840
130 LOAD"commonxx",&1A40
140 :'**** Instant hyperspace ****
145 POKE &4C56,24
146 POKE &507F,0
150 :'**** Inf fuel ****
170 POKE &4F02,0
180 :'**** Inf miss ****
190 POKE &382D,0
200 :'**** no hyp range linit ****
210 POKE &4C08,0:POKE &4C12,0
220 :'**** const galac jump ****
230 POKE &4BFA,0
240 :'**** const escap pod ****
250 POKE &3849,0
260 :'**** No cargo loss on use of esc *
270 POKE &3866,0
280 :'**** No energy loss ****
290 POKE &35CB,0
300 :'**** No laser temp rise ****
310 POKE &7A4F,0
320 :'**** One hit to destroy ships ****
330 POKE &7AA8,0
340 :'**** Spast launch thargoids ****
350 POKE &896B,0
360 :'**** Miss able to blow up spst **
370 POKE &8A8F,0
380 :'**** Cloaking (Y) ****
390 POKE &4902,&21:POKE &4906,&F6:POKE &4908,&0
400 :'**** Inf credits ****
410 POKE &FE78,3:POKE &FE86,&18
420 :'**** ECM jammer ****
430 POKE &8932,&18:POKE &48C3,0
440 POKE &48CD,0
450 :'**** Const energy bomb ****
460 POKE &2F6A,0
470 :'**** Remove flash ****
480 POKE &2F7A,&C9
490 :'**** Make indestructible ****
500 POKE &787C,&0:POKE &7B61,0:POKE &1E63,&C3
510 :'**** Start prog ****
520 CALL &1C82

Auteur :  Princesse Mariana [ 01 Mai 2020, 18:27 ]
Sujet du message :  Re: ELITE

Citer :
"Commander Thomas ... derzeitiges System: Geisgeza ... Hyperraumziel: Arexe ... Treibstoff: 7.0 Lichtjahre ... Konto: 65 Mio. Cr. ... Strafregister: sauber ... Einstufung: Elite... Ausrüstung: Zusatz-Laderaum... E.C.M.-System ... E.C.M.-Störmechanismus ... Raumgreifer ... Rettungskapsel ... Energiebombe ... Zusatz-Energieakku ... Lande-Computer ... galaktischer Hyperraumantrieb ... Tarnme-chanismus ... Militärlaser vorne ... Militärlaser hinten ... Militärlaser links ... Militärlaser rechts"

Dies ist meine aktuelle Statusseite im Spiel ELITE, die ich nach ganzen zwei Tagen erreichte! Leider kann ich Ihnen jedoch keinen Planeten verraten, auf dem u.a. eine solche "wunderbare Credit-Vermehrung" stattfindet. Aber vielleicht genügt Ihnen vorerst das untenstehende Programm: Das Programm macht nichts anderes, als auf Kassette einen Commander zu erzeugen, der anschließend vom ELITE-Programm wieder geladen werden kann. Dieser Commander wird ausschließlich im Dialog mit dem User zusammengestellt, so daß das Programm für jeden, der mit der ELITE-Terminologie vertraut ist, ohne weiteres verständlich ist.

Ein Hinweis jedoch zu der Abfrage "System eingeben?": Tippen Sie "J" oder "j", so erwartet der Rechner die Eingabe der Koordinaten des gewünschten Systems, bezogen auf die jeweilige galaktische Karte, anschließend die technische Stufe. Eine direkte Eingabe des Planetennamens ist leider nicht möglich (Sonst müßte das Programm die Koordinaten sämtlicher Planeten kennen - und Sie wären eine Weile mit dem Abtippen beschäftigt!). Geben Sie jedoch "N" oder "n" ein, so wählt der Rechner die Koordinaten eines Planeten in der Mitte der jeweiligen Galaxie. Natürlich sollen Sie das Programm nicht dazu benutzen. sich sofort zum "Elite-Kämpfer" zu befördern (es käme ja auch niemand auf die Idee, beim Würfelspiel die Figuren gleich ins Ziel zu setzen). Es eignet sich aber hervorragend dazu, schon einmal auszuprobieren, ob z.B. an den Seiten Laser notwendig sind oder nicht. Bei sinnvoller Anwendung dieses Programms bleibt ELITE ein Spiel, das so schnell nicht langweilig wird.

Thomas Kochmann , CPCAI 90-02


Code :
40 MEMORY &9FFF
50 FOR i=&A000 TO &A067:POKE i,0:NEXT
80 RESTORE 130:DIM par(7,8)
90 FOR gal=1 TO 8
100 FOR i=0 TO 8:READ x$
110 par(gal-1,i)=VAL("&"+x$)
120 NEXT:NEXT
130 DATA 4A,5A,48,02,53,B7,79,85,09
140 DATA 94,B4,90,04,A6,6F,83,84,06
150 DATA 29,69,21,08,4D,DE,78,82,0C
160 DATA 52,D2,42,10,9A,BD,7A,86,07
170 DATA A4,A5,84,20,35,7B,90,80,05
180 DATA 49,4B,09,40,6A,F6,75,82,07
190 DATA 92,96,12,80,D4,ED,7C,7F,09
200 DATA 25,2D,24,01,A9,DB,7B,80,07
230 MODE 1:LOCATE 8,2
240 PRINT"** Commander fuer ELITE **"
250 LOCATE 1,5
280 INPUT"Name des Commanders";a$
290 PRINT:PRINT:a$=UPPER$(LEFT$(a$,10))
300 FOR i=1 TO LEN(a$)
310 POKE &9FFF+i,ASC(MID$(a$,i,1))
320 NEXT:POKE &9FFF+i,0
350 PRINT"Derzeitiges System:":PRINT
360 INPUT"Galaxie Nr.";x:PRINT
370 x=x-1:x=x MOD 8: POKE &A011,x
380 FOR i=0 TO 5
390 POKE &A03C+i,par(x,i):NEXT
400 POKE &A043,par(x,6)
410 POKE &A045,par(x,7)
420 POKE &A048,par(x,8)
430 INPUT"System eingeben (J/N)";a$
440 IF UPPER$(a$)<>"J"THEN 540
450 PRINT:PRINT"x-Koordinate:  ";
460 PRINT"links: 0  rechts: 255"
470 PRINT"y-Koordinate:  ";
480 PRINT"oben:  0  unten:  255"
490 PRINT:INPUT"x-Koordinate";x
500 INPUT"y-Koordinate";y
510 POKE &A043,x:POKE &A045,y
520 PRINT:INPUT"Technische Stufe";x
530 POKE &A048,MIN(x-1,255)
540 POKE &A065,&FF
550 PRINT:PRINT
580 INPUT"Treibstoff (Lj.)";x   
590 x=MIN(10*x,255):POKE &A02E,x 
600 PRINT:PRINT
630 INPUT"Konto (Cr)";x:PRINT:PRINT
640 a=INT(x/1000):b=(x-1000*a)*10
650 a=MIN(a,65535)
660 POKE &A012,a-256*INT(a/256)
670 POKE &A013,INT(a/256)
680 POKE &A014,b MOD 256
690 POKE &A015,INT(b/256)
720 PRINT"Strafregister:":PRINT
730 PRINT"         0 = Sauber"
740 PRINT" 1 bis  49 = Vorbestraft"
750 PRINT"50 bis 255 = Gesucht"
760 PRINT:INPUT"Wert";x
770 POKE &A00B,x:PRINT:PRINT
800 PRINT"Einstufung:":PRINT
810 PRINT"      0 bis    2303 = ";
820 PRINT"Harmlos"
830 PRINT"   2304 bis    4351 = ";
840 PRINT"Relativ Harmlos"
850 PRINT"   4352 bis    8447 = ";
860 PRINT"Schwach"
870 PRINT"   8448 bis   16639 = ";
880 PRINT"Durchschnitt"
890 PRINT"  16640 bis   33023 = ";
900 PRINT"Ueberdurschnitt"
910 PRINT"  33024 bis  196607 = ";
920 PRINT"Kompetent"
930 PRINT" 196608 bis  720895 = ";
940 PRINT"Gefaehrlich"
950 PRINT" 720896 bis 1703935 = ";
960 PRINT"Toedlich"
970 PRINT"1703936 bis ....... = ";
980 PRINT"Elite"
990 PRINT:INPUT"Wert";x
1000 a=INT(x/65536):x=x-65536*a
1010 b=INT(x/256):c=x-256*b
1020 POKE &A00C,c:POKE &A00D,b
1030 POKE &A00E,a:PRINT:PRINT
1060 PRINT"Ausruestung:":PRINT
1070 INPUT"Raketen: Anzahl";x:PRINT
1080 POKE &A02F,x MOD 256
1090 RESTORE 1140: FOR n=1 TO 8
1100 READ a$,i:PRINT a$;" (J/N)";
1110 PRINT TAB(26):INPUT a$
1120 x=0:IF UPPER$(a$)="J" THEN x=&FF
1130 POKE i,x:NEXT
1140 DATA Zusatz-Laderaum,&A030
1150 DATA E.C.M.-System,&A031
1160 DATA Raumgreifer,&A034
1170 DATA Rettungskapsel,&A035
1180 DATA Energiebombe,&A036
1190 DATA Zusatz-Energieakku,&A037
1200 DATA Lande-Computer,&A038
1210 DATA Gal. Hyperrumantr.,&A039
1220 PRINT"Tarnmechanismus (J/N)";
1230 PRINT TAB(26):INPUT a$
1240 x=0: IF UPPER$(a$)="J"THEN x=&40
1250 PRINT"E.C.M.-Stoermech. (J/N)";
1260 PRINT TAB(26):INPUT a$
1270 IF UPPER$(a$)="J"THEN x=x OR &80
1280 POKE &A05C,x
1290 PRINT:PRINT"Laser:  0=keiner"
1300 PRINT TAB(9)"1=Impuls-Laser"
1310 PRINT TAB(9)"2=Strahlen-Laser"
1320 PRINT TAB(9)"3=Militaer-Laser"
1330 PRINT TAB(9)"4=Asteroiden-Laser"
1340 PRINT
1350 INPUT"vorne ";x:POKE &A029,x
1360 INPUT"hinten";x:POKE &A02A,x
1370 INPUT"links ";x:POKE &A02B,x
1380 INPUT"rechts";x:POKE &A02C,x
1390 PRINT:PRINT
1420 PRINT"Inventar:":PRINT
1430 a=&A017:GOSUB 1850:PRINT
1440 INPUT"Freier Laderaum (t)";x
1450 x=MIN(x,255):POKE &A028,x
1460 PRINT:PRINT
1490 PRINT"Lagerbestand im"
1500 PRINT"derzeitigen System:"
1510 PRINT:a=&A04A:GOSUB 1850
1520 PRINT:PRINT
1560 x=0:FOR i=&A000 TO &A065
1570 x=x XOR PEEK(i):NEXT
1580 POKE &A066,x
1590 x=0:FOR i=&A000 TO &A066
1600 x=x+PEEK(i):NEXT
1610 POKE &A067,x MOD 256
1620 RESTORE 1650:FOR i=&A000 TO &A067
1630 READ x$:x=VAL("&"+x$)
1640 POKE i, PEEK(i) XOR x:NEXT
1650 DATA 21,16,4F,CD,C3,6B,21,20
1660 DATA 10,11,73,4F,01,09,00,ED
1670 DATA B0,11,F1,69,CD,4D,64,76
1680 DATA 76,76,76,76,76,CD,7B,7B
1690 DATA 32,7C,4F,CD,86,6B,32,7D
1700 DATA 4F,CD,6B,6B,3E,02,CD,CA
1710 DATA 6B,CD,A8,56,CD,BA,6B,CD
1720 DATA 50,CE,FB,CD,6B,6B,3E,97
1730 DATA CD,CA,6B,21,01,0C,22,0F
1740 DATA 4F,3E,04,CD,26,63,CD,57
1750 DATA 68,D6,15,E6,0F,5F,32,67
1760 DATA B6,3A,28,4F,57,32,68,6B
1770 DATA 3A,29,4F,6F,32,69,6B,7D
1800 CALL &BB03
1810 SAVE"",b,&A000,&68
1820 PRINT:PRINT:END
1850 INPUT"Nahrung (t)    ";x
1860 GOSUB 2180
1870 INPUT"Textilien (t)  ";x
1880 GOSUB 2180
1890 INPUT"Spaltstoffe (t)";x
1900 GOSUB 2180
1910 INPUT"Sklaven (t)    ";x
1920 GOSUB 2180
1930 INPUT"Spirituosen (t)";x
1940 GOSUB 2180
1950 INPUT"Luxusgueter (t)";x
1960 GOSUB 2180 
1970 INPUT"Rauschgifte (t)";x
1980 GOSUB 2180
1990 INPUT"Computer (t)   ";x
2000 GOSUB 2180
2010 INPUT"Maschinen (t)  ";x
2020 GOSUB 2180 
2030 INPUT"Legierungen (t)";x
2040 GOSUB 2180 
2050 INPUT"Waffen (t)     ";x
2060 GOSUB 2180
2070 INPUT"Felle (t)      ";x
2080 GOSUB 2180 
2090 INPUT"Mineralien (t) ";x
2100 GOSUB 2180
2110 INPUT"Gold (kg)      ";x
2120 GOSUB 2180
2130 INPUT"Platin (kg)    ";x
2140 GOSUB 2180
2150 INPUT"Edelsteine (g) ";x
2160 GOSUB 2180
2170 RETURN
2180 x=MIN(x,255):POKE a,x
2190 a=a+1:RETURN

Page 1 sur 1 Le fuseau horaire est UTC+1 heure
Powered by phpBB® Forum Software © phpBB Group
https://www.phpbb.com/