10 REM ####        * ESQUIVE *
20 REM #### CREATEUR : BARONE Sylvain ####
30 REM ####        9 AOUT 1985        ####
40 REM ####   VERSION 2.0 ( HARD )    ####
50 REM --- PRESENTATION ---
60 MODE 1:INK 0,0:INK 1,10,25:INK 2,7:INK 3,19:SPEED INK 50,50:PAPER 0:PEN 1:BORDER 7
70 SYMBOL AFTER 64
80 LOCATE 1,5:  PRINT"EEEE   SSSS  QQQQ  U  U IIII  V  V  EEEE"
90 LOCATE 1,6:  PRINT"E      S     Q  Q  U  U  II   V  V  E"
100 LOCATE 1,7: PRINT"E      S     Q  Q  U  U  II   V  V  E"
110 LOCATE 1,8: PRINT"EEE    SSSS  Q  Q  U  U  II   V  V  EEE"
120 LOCATE 1,9: PRINT"E         S  Q  Q  U  U  II   V  V  E"
130 LOCATE 1,10:PRINT"E         S  Q QQ  U  U  II   V  V  E"
140 LOCATE 1,11:PRINT"EEEE   SSSS  QQQQ  UUUU IIII   VV   EEEE"
150 LOCATE 1,12:PRINT"                 Q"
160 LOCATE 7,17:PEN 2:PRINT"CREATEUR : BARONE Sylvain"
170 LOCATE 10,20:PEN 3:PRINT CHR$(164)" COPYRIGHT AOUT 1985"
180 FOR i=1 TO 1000: NEXT
190 FOR i=1 TO 700:CALL &BD24:CALL &BD25:CALL &BD23:NEXT
200 FOR i=1 TO 1000: NEXT
210 LOCATE 10,23:PRINT"REGLES DU JEU ( O/N )"
220 z$=UPPER$(INKEY$):IF z$="" THEN 220
230 IF Z$="O" THEN 260
240 IF Z$="N" THEN 490
250 GOTO 220
260 REM ---- REGLES ----
270 CLS:INK 2,15:INK 1,23:INK 3,0,25:PEN 1
280 df=149:RESTORE 2450:FOR i=1 TO 2:READ a,b,c,d,e,f,g,h:SYMBOL df,a,b,c,d,e,f,g,h:df=df+1:next
290 RESTORE 2480:FOR i=1 TO 2:READ a,b,c,d,e,f,g,h:SYMBOL df,a,b,c,d,e,f,g,h:df=df+1:next
300 LOCATE 14,1:PRINT"R E G L E S"
310 PRINT:PRINT"Vous voici a l'interieur d'un labyrinthe ";:PEN 1:PRINT"ensorcele .":PEN 2
320 PRINT"Votre but est de prendre tous les objets qui ";:PEN 3:PRINT"clignotent":PEN 1
330 PRINT:LOCATE 12,9:PRINT"Seulement voila  ":pen 2
340 PRINT:PRINT"Des rochers detectent vos moindres mou-  vements et devalent sur vous si vous    etes dans leur alignement "
350 PRINT:PRINT"Si cela arrive vous pourrez vous refu-   gier dans un refuge."
360 PRINT:PRINT"Heureusement, la premiere fois que vous  passerez devant un rocher il ne reagi-  ra pas"
370 PRINT:PRINT"Malheureusement, les refuges se ferment  apres deux utilisations. Et plus de     rochers vous suivent, moins vous allez  vite(Ah !)"
380 LOCATE 35,25:PEN 3:PRINT"--->":PEN 2
390 WHILE INKEY$="":WEND
400 CLS
410       PRINT"Il y a trois labyrinthes et valeur des   objets augemente a chaque labyrinthe  "
420 PRINT:PRINT:PEN 3:PRINT"--> ";:PEN 1:PRINT"1 er.LABYRINTHE :":PEN 2:PRINT:PRINT TAB(5)+CHR$(149)+" 50 Pts"+SPACE$(10)+CHR$(150)+" 10 Pts"
430 PRINT:PRINT:PEN 3:PRINT"--> ";:PEN 1:PRINT"2 eme LABYRINTHE :":PEN 2:PRINT:PRINT TAB(5)+CHR$(151)+" 100 Pts"+SPACE$(9)+CHR$(152)+" 150 Pts"
440 PRINT:PRINT:PEN 3:PRINT"--> ";:PEN 1:PRINT"3 eme LABYRINTHE :":PEN 2:PRINT:PRINT TAB(5)+CHR$(150)+" 150 Pts"+SPACE$(9)+CHR$(152)+" 200 Pts"
450 PRINT:PRINT"Vous pourrez vous deplacer soit avec un  joystick soit grace aux touches :"
460 PRINT:PRINT"\ --> DROITE                / --> GAUCHEA --> HAUT                  Z --> BAS";
470 LOCATE 6,25:PEN 3:PRINT"B O N N E  C H A N C E  ! ! !"
480 WHILE INKEY$="":WEND
490 CLS:PEN 2
500 LOCATE 8,12:PRINT"<J>OYTICK OU <C>LAVIER"
510 z$=UPPER$(INKEY$):IF z$<>"J" AND z$<>"C" THEN 510
520 IF z$="J" THEN manette=1 ELSE manette=-1
530 ENT 1,120,-40,10:SOUND 1,284,50,15,0,1:SOUND 2,284,50,15,0,1:sc=555:GOSUB 2650:sc=0:
540 RESTORE 2440
550 FOR i=47001 TO 47001+PEEK(47020):sc$=sc$+STR$(PEEK(i)):NEXT:sc=VAL(sc$)
560 FOR i=47011 TO 47011+PEEK(47021):hsc$=hsc$+STR$(PEEK(i)):NEXT:hsc=VAL(hsc$)
570 IF sc>hsc THEN hsc=sc
580 IF PEEK(47022)=1 THEN ta=2:vie=1+PEEK(47023):RESTORE 2470:GOTO 600
590 IF PEEK(47022)=2 THEN ta=3:vie=1+PEEK(47023):RESTORE 2500 ELSE vie=3:Sc=0:ta=1
600 DIM m(40,25):DIM box(14):DIM boy(14):DIM refx(120):DIM refy(120):DIM psi(14):DIM dir(14):DIM tem(14)
610 sy=129:y=2:r=1:bo1=-1:bo2=-1:cl=0
620 FOR i=1 TO 3:READ a,b,c,d,e,f,g,h:SYMBOL sy,a,b,c,d,e,f,g,h:sy=sy+1:NEXT
630 boule$=CHR$(129):clef1$=CHR$(130):clef2$=CHR$(131):t1$=" ":t2$=CHR$(128):t3$=CHR$(143):j1$=CHR$(248):j2$=CHR$(250):j3$=CHR$(251)
640 point1(1)=50: point2(1)=100:\
    point1(2)=100: point2(2)=150:\
    point1(3)=150: point2(3)=200
650 va1(1)=VAL("2"):va2(1)=VAL("2.1"):va1(2)=VAL("2.2"):va2(2)=VAL("2.3"):va1(3)=VAL("2.4"):va2(3)=VAL("2.5")
660 l1$=t1$+t3$+t3$+clef2$+t3$+t3$:l2$=t1$+clef2$+t3$+t3$+t3$+clef1$
670 l3$=t1$+t3$+t3$+clef1$+t3$+t3$:l4$=t1$+clef1$+t3$+t3$+t3$+clef1$
680 l5$=t1$+clef1$+t3$+t3$+t3$+clef2$
690 MODE 1:INK 1,6:INK 2,18:INK 3,2,11:INK 0,0:SPEED INK 50,50
700 y=2
710 REM ---- DECOR ----
720 WINDOW#1,1,40,1,1:PEN#1,2:LOCATE#1,1,1:PRINT#1,CHR$(250)+" :"+STR$(vie):LOCATE#1,15,1:PRINT#1,"SCORE :"+STR$(sc):LOCATE#1,35,1:PEN#1,3:PRINT#1,STR$(ta)+" UP":PEN#1,2
730 WINDOW#2,1,40,25,25:PEN#2,2:LOCATE#2,1,1:PRINT#2,"HIGH SCORE :"+STR$(hsc):LOCATE #2,21,1:PRINT#2,"BONUS : 0":PEN#2,3:LOCATE#2,35,1:PRINT#2,STR$(ta)+" UP":PEN#2,2
740 ta$=""
750 FOR i=1 TO 6:ta$=ta$+t2$+STRING$(5,t3$):NEXT:ta$=t3$+ta$+t2$+t3$:GOSUB 2530
768 ta$=t2$+t1$+STRING$(36,t1%)+t2$:GOSUB 2530
770 ta$=t3$+l1$+l1$+l1$+l1$+l1$+l1$+t1$+t3$:GOSUB 2530
780 ta$=t3$+l2$+l4$+l4$+l4$+l4$+l5$+t1$+t3$:GOSUB 2530
790 ta$=t3$+l3$+l3$+l3$+l3$+l3$+l3$+t1$+t3$:GOSUB 2530
800 ta$=t2$+STRING$(37,t1$)+t2$+t2$:GOSUB 2530
810 FOR g=1 TO 3
820 ta$=t3$+l3$+l3$+l3$+l3$+l3$+l3$+t1$+t3$:GOSUB 2530:ta$=t3$+l2$+l4$+l4$+l4$+l4$+l5$+t1$+t3$:GOSUB 2530:ta$=t3$+l3$+l3$+l3$+l3$+l3$+l3$+t1$+t3$:GOSUB 2530:ta$=t2$+t1$+STRING$(36,t1$)+t2$:GOSUB 2530
830 NEXT g
840 ta$=t3$+l3$+l3$+l3$+l3$+l3$+l3$+t1$+t3$:GOSUB 2530
850 ta$=t3$+l2$+l4$+l4$+l4$+l4$+l5$+t1$+t3$:GOSUB 2530
860 ta$=t3$+l1$+l1$+l1$+l1$+l1$+l1$+t1$+t3$:GOSUB 2530
870 ta$=t2$+t1$+STRING$(36,t1$)+t2$:GOSUB 2530
880 ta$=""
890 FOR i=1 TO 6:ta$=ta$+t2$+STRING$(5,t3$):NEXT i:ta$=t3$+ta$+t2$+t3$:GOSUB 2530
900 REM ---- POSITION DES ROCHERS ----
910 GOSUB 2310
920 REM ---- ACTION ----
930 REM ---- POSITION JOUEUR ----
940 GOSUB 2350
950 EVERY 16,3 GOSUB 1810
960 REM ---- TEST MOUVEMENTS ----
970 IF manette=1 THEN 1050 ELSE 980
980 DI
990 IF INKEY(69)=0 THEN mv=1:GOTO 1030
1000 IF INKEY(71)=0 THEN mv=2:GOTO 1030
1010 IF INKEY(30)=0 THEN mv=3:GOTO 1030
1020 IF INKEY(22)=0 THEN mv=4
1030 ON mv GOSUB 1130,1280,1430,1580
1040 EI:GOTO 980
1050 DI
1060 IF INKEY(72)=0 THEN mv=1:GOTO 1110
1070 IF INKEY(73)=0 THEN mv=2:GOTO 1110
1080 IF INKEY(74)=0 THEN mv=3:GOTO 1110
1090 IF INKEY(75)=0 THEN mv=4:GOTO 1110
1100 mv=0
1110 ON mv GOSUB 1130,1280,1430,1580
1120 EI:GOTO 1050
1130 REM ---- MVT EN HAUT ---
1140 IF m(x,y-1)=-1 THEN 1240
1150 IF m(x,y-1)=0 THEN GOSUB 1250:GOTO 1240
1168 IF m(x,y-1)>=2 THEN 1170 ELSE 1240
1170 IF m(x,y-1)=va1(ta) THEN sc=sc+Point1(ta):m(x,y-1)=3:GOSUB 1970:GOSUB 1250:GOTO 1240
1180 IF m(x,y-1)=va2(ta) THEN sc=sc+Point2(ta):m(x,y-1)=3:GOSUB 1970:GOSUB 1250:GOTO 1240
1190 IF m(x,y-1)>=3 THEN 1200 ELSE 1240
1200 m(x,y-1)=m(x,y-1)+1:IF m(x,y-1)>=5 THEN rex=x:rey=y-1:GOSUB 1250:EI:GOTO 1210 ELSE 1240
1210 IF manette=1 THEN 1220 ELSE 1230
1220 WHILE INKEY(73)=-1:WEND:DI:GOSUB 1280:GOSUB 1730:GOTO 1240
1230 WHILE INKEY(71)=-1:WEND:DI:GOSUB 1280:GOSUB 1730
1240 RETURN
1250 LOCATE x,y:PEN 0:PRINT t1$:y=y-1:LOCATE x,y:PEN 2:PRINT j1$
1260 GOSUB 1930
1270 RETURN
1280 REM ---- MVT EN BAS ----
1290 IF m(x,y+1)=-1 THEN 1390
1300 IF m(x,y+1)=0 THEN GOSUB 1400:GOTO 1390
1310 IF m(x,y+1)>=2 THEN 1320 ELSE 1390
1320 IF m(x,y+1)=va1(ta) THEN sc=sc+point1(ta):m(x,y+1)=3:GOSUB 1970:GOSUB 1400:GOTO 1390
1330 IF m(x,y+1)=va2(ta) THEN sc=sc+point2(ta):m(x,y+1)=3:GOSUB 1970:GOSUB 1400:GOTO 1390
1340 IF m(x,y+1)>=3 THEN 1350 ELSE 1390
1350 m(x,y+1)=m(x,y+1)+1:IF m(x,y+1)>=5 THEN rex=x:rey=y+1:GOSUB 1400:EI:GOTO 1360 ELSE 1420
1360 IF manette=1 THEN 1370 ELSE 1380
1370 WHILE INKEY(72)=-1:WEND:DI:GOSUB 1130:GOSUB 1730:GOTO 1390
1380 WHILE INKEY(69)=-1:WEND:DI:GOSUB 1130:GOSUB 1730
1390 RETURN
1400 LOCATE x,y:PEN 0:PRINT t1$:y=y+1:LOCATE x,y:PEN 2:PRINT  j1$
1410 GOSUB 1930
1420 RETURN
1430 REM ---- MVT A GAUCHE ----
1440 IF m(x-1,y)=-1 THEN 1540
1450 IF m(x-1,y)=0 THEN GOSUB 1550:GOTO 1540
1460 IF m(x-1,y)>=2 THEN 1470 ELSE 1540
1470 IF m(x-1,y)=va1(ta) THEN sc=sc+Point1(ta):m(x-1,y)=3:GOSUB 1970:GOSUB 1550:GOTO 1540
1480 IF m(x-1,y)=va2(ta) THEN sc=sc+Point2(ta):m(x-1,y)=3:GOSUB 1970:GOSUB 1550:GOTO 1540
1490 IF m(x-1,y)>=3 THEN 1500 ELSE 1540
1500 m(x-1,y)=m(x-1,y)+1:IF m(x-1,y)>=5 THEN rex=x-1:rey=y:GOSUB 1550:EI:GOTO 1510 ELSE 1540
1510 IF manette=1 THEN 1520 ELSE 1530
1520 WHILE INKEY(75)=-1:WEND:DI:GOSUB 1580:GOSUB 1730:GOTO 1540
1530 WHILE INKEY(22)=-1:WEND:DI:GOSUB 1580:GOSUB 1730
1540 RETURN
1550 LOCATE x,y:PEN 0:PRINT t1$:x=x-1:LOCATE x,y:PEN 2:PRINT j3$
1560 GOSUB 1930
1570 RETURN
1580 REM ---- MVT A DROITE ----
1590 IF m(x+1,y)=-1 THEN 1690
1600 IF m(x+1,y)=0 THEN GOSUB 1700:GOTO 1690
1610 IF m(x+1,y)>=2 THEN 1620 ELSE 1690
1620 IF m(x+1,y)=va1(ta) THEN sc=sc+Point1(ta):m(x+1,y)=3:GOSUB 1970:GOSUB 1700:GOTO 1690
1630 IF m(x+1,y)=va2(ta) THEN sc=sc+Point2(ta):m(x+1,y)=3:GOSUB 1970:GOSUB 1700:GOTO 1690
1640 IF m(x+1,y)>=3 THEN 1650 ELSE 1690
1650 m(x+1,y)=m(x+1,y)+1:If m(x+1,y)>=5 THEN rex=x+1:rey=y:GOSUB 1700:EI:GOTO 1660 ELSE 1690
1660 IF manette=1 THEN 1670 ELSE 1680
1670 WHILE INKEY(74)=-1:WEND:DI:GOSUB 1430:GOSUB 1730:GOTO 1690
1680 WHILE INKEY(30)=-1:WEND:DI:GOSUB 1430:GOSUB 1730
1690 RETURN
1700 LOCATE x,y:PEN 0:PRINT t1$:x=x+1:LOCATE x,y:PEN 2:PRINT j2$
1710 GOSUB 1930
1720 RETURN
1730 REM ---- REBOUCHAGE DES REFUGES ---- 
1740 LOCATE rex,rey:PEN 1:PRINT t3$:m(rex,rey)=1
1750 RETURN
1760 REM ---- DETECTION DES ROCHERS ----
1770 k=(x+4)/6:GOTO 1790
1780 k=7+(y+1)/4
1790 tem(k)=1:psi(k)=-psi(k):dir(k)=-dir(k)
1800 RETURN
1810 REM -- DEPLACE ROCHERS ---
1820 FOR p=1 TO 13
1830 IF tem(p)=1 THEN bo=bo-1:GOTO 1840 ELSE 1910
1840 IF dir(p)=1 THEN 1850 ELSE 1860
1850 IF box(p)+1<40 THEN LOCATE box(p),boy(p):PRINT t1$:box(p)=box(p)+1:LOCATE box(p),boy(p):PRINT boule$:GOSUB 2160:GOTO 1910 ELSE tem(p)=-1:GOTO 1910
1860 IF dir(p)=-1 THEN 1870 ELSE 1880
1870 IF box(p)-1>0 THEN LOCATE box(p),boy(p):PRINT t1$:box(p)=box(p)-1:LOCATE box(p),boy(p):PRINT boule$:GOSUB 2160:GOTO 1910 ELSE tem(p)=-1:GOTO 1910
1880 IF dir(p)=2 THEN 1890 ELSE 1900
1890 IF boy(p)+1<25 THEN LOCATE box(p),boy(p):PRINT t1$::boy(p)=boy(p)+1:LOCATE box(p),boy(p):PRINT boule$:GOSUB 2160:GOTO 1910 ELSE tem(p)=-1:GOTO 1910
1900 IF boy(p)-1>1 THEN LOCATE box(p),boy(p):PRINT t1$:boy(p)=boy(p)-1:LOCATE box(p),boy(p):PRINT boule$:GOSUB 2160 ELSE tem(p)=-1
1910 NEXT
1920 RETURN
1930 REM ----
1940 IF (x=2 AND tem(1)=-1) OR (x=8 AND tem(2)=-1) OR (x=14 AND tem(3)=-1) OR (x=20 AND tem(4)=-1) OR (x=26 AND tem(5)=-1) OR (x=32 AND tem(6)=-1) OR (x=38 AND tem(7)=-1) THEN GOSUB 1760
1950 IF (y=3 AND tem(8)=-1) OR (y=7 AND tem(9)=-1) OR (y=11 AND tem(10)=-1) OR (y=15 AND tem(11)=-1) OR (y=19 AND tem(12)=-1) OR (y=23 AND tem(13)=-1) THEN GOSUB 1780
1960 RETURN 
1970 REM ---- SCORE ----
1980 LOCATE #1,15,1:PRINT #1,"SCORE:";sc 
1990 cl=cl+1:ENT 1,30,-20,1:SOUND 1,284,20,15,0,1:SOUND 2,204,20,15,0,1
2000 IF cl>=40 AND bo1=-1 THEN bo1=-1:bonus=500*ta+100*vie:GOSUB 2050:GOTO 2030
2010 IF cl>=80 AND bo2=-1 THEN bo2=-1:bonus=1000*ta+200*vie:GOSUB 2050:GOTO 2030
2020 IF cl>=120 AND bo2=-1 THEN bonus=2000*ta+500*vie:GOSUB 2050:GOSUB 2640:IF ta=3 THEN LOCATE 1,11:PRINT"BON J'ABANDONNE ... VOUS ETES UN PEU              TROP FORT POUR MOI ...":GOSUB 2250 ELSE GOSUB 2640:POKE 47022,ta:POKE 47023,vie:RUN
2030 RETURN
2040 END
2050 REM ---- BONUS ----
2060 FOR i=0 TO bonus STEP 100
2070 LOCATE 14,11:PRINT"BONUS :"+STR$(i)
2080 LOCATE #2,21,1:PRINT#2,"BONUS :"+STR$(i)
2090 ENT 1,30,30,5:SOUND 1,20,10,15,0,1::SOUND 2,20,10,15,0,1
2100 NEXT
2110 FOR i=1 TO 1000:NEXT 
2120 LOCATE#2,21,1:PRINT#2,"BONUS : 0     "
2130 LOCATE 14,11:PRINT SPACE$(20)
2140 sc=sc+bonus:LOCATE#1,15,1:PRINT#1,"SCORE :";sc
2150 RETURN
2160 REM ---- VERIFIE ---- 
2170 Di
2180 iF box(P)=x AND boy(P)=y THEN 2190 ELSE 2300
2190 vie=vie-1:ENT 1,100,10,1:SOUND 1,204,110,15,0,1:SOUND 2,204,110,15,0,1:LOCATE#1,1,1:PRINT#1,"VIE :"+STR$(vie)
2200 IF vie<=0 THEN 2250 ELSE 2210
2210 FOR l=1 TO 5:LOCATE box(p),boy(p):PRINT j1$:FOR te=1 TO 200:NEXT te:LOCATE box(p),boy(p):PRINT boucle$:FOR te=1 TO 200:NEXT te:NEXT l
2220 FOR l=1 TO 13:LOCATE box(p),boy(p):PRINT t1$:NEXT l
2230 GOSUB 2310:GOSUB 2350
2240 GOTO 2300
2250 LOCATE 14,9:PRINT"UNE AUTRE ?"
2260 z$=UPPER$(INKEY$)
2270 IF  z$="N" THEN LOCATE 10,14:PEN 3:PRINT "Mauvais perdant !!!":END
2280 IF  z$="O" THEN GOSUB 2640:POKE 47022,0:POKE 47023,0:RUN
2290 GOTO 2260
2300 EI:RETURN
2310 REM ---- 
2320 h=2:PEN 2:FOR l=1 TO 7:Box(l)=h:Boy(l)=2:tem(l)=-1:Psi(l)=2:dir(l)=2:h=h+6:LOCATE box(l),boy(l):PRINT boule$:NEXT
2330 h=3:PEN 2:FOR l=8 TO 13:Box(l)=1:Boy(l)=h:tem(l)=-1:Psi(l)=1:dir(l)=1:LOCATE box(l),boy(l):PRINT boule$:h=h+4:NEXT
2340 RETURN
2350 REM ---- 
2360 RANDOMIZE TIME
2370 r1=INT(RND*120):iF r1<1 OR r1>120 THEN 2370
2380 r2=INT(RND*120):IF r2<1 OR r2>120 THEN 2380
2390 x=refx(r1):y=refy(r2):IF m(x,y)<2 THEN RANDOMIZE TIME:GOTO 2360
2400 if m(x,y)=va1(ta) THEN cl=cl+1:sc=sc+point1(ta):m(x,y)=3
2410 if m(x,y)=va2(ta) THEN cl=cl+1:sc=sc+point2(ta):m(x,y)=3
2420 ENT 1,30,-20,1:FOR i=1 TO 10:FOR te=1 TO 50:NEXT te:SOUND 1,204,20,15,0,1:SOUND 2,284,20,15,0,1:LOCATE x,y:PRINT j1$:NEXT i
2430 RETURN
2440 DATA 0,&X111100,&X1111110,&X1\
111110,&X1111110,&X1111110,&X11110\
0,0
2450 DATA 0,&X111000,&X1000,&X1100\
0,&X1000,&X111100,&X100100,&X111100 
2460 DATA &X11101111,&X101001,&X11\
01111,&X100100,&X100100,&X11110110\
,&X10010100,&X11110111
2470 DATA 0,&X111100,&X111110,&X11\
111110,&X1111110,&X1111110,&X111100,0
2480 DATA &X0111110,&X1111110,&X11\
11110,&X1111110,&X111100,&X11000,&\
X11000,&X111100
2490 DATA &X11100111,&X11100010,&X\
11100010,&X11100111,&X11100111,&X1\
000111,&X1000111,&X11100111
2500 DATA 0,&X111100,&X1111110,&X1\
111110,&X1111110,&X1111110,&X111100,0
2510 DATA &X11101111,&X101001,&X11\
01111,&X100100,&X100100,&X11110110\
,&X10010100,&X11110111
2520 DATA &X11100111,&X11100010,&X\
11100010,&X11100111,&X11100111,&X1\
000111,&X1000111,&X11100111
2530 REM ---- MEMORISE ----
2540 FOR j=1 TO LEN(ta$)
2550 as$=MID$(ta$,j,1):as=ASC(as$)
2560 IF as=32 THEN m(j,y)=0:LOCATE j,y:PRINT as$:GOTO 2610
2570 IF as=143 THEN m(j,y)=1:LOCATE j,y:PEN 1:PRINT as$:GOTO 2610
2580 IF as=128 THEN m(j,y)=-1:LOCATE j,y:PRINT as$:GOTO 2610
2590 IF as=130 THEN m(j,y)=va1(ta):LOCATE j,y:PEN 3:PRINT as$:refx(r)=j:refy(r)=y:r=r+1:GOTO 2610
2600 IF as=131 THEN m(j,y)=va2(ta):LOCATE j,y:PEN 3:PRINT as$:refx(r)=j:refy(r)=y:r=r+1
2610 NEXT j
2620 y=y+1
2630 RETURN
2640 REM ----
2650 FOR i=1 TO LEN(STR$(sc)):POKE 47000+i,VAL(MID$(STR$(sc),i,1)):NEXT
2660 FOR i=1 TO LEN(STR$(hsc)):POKE 47010+i,VAL(MID$(STR$(hsc),i,1)):NEXT
2670 POKE 47020,LEN(STR$(sc))-1:POKE 47021,LEN(STR$(hsc))-1
2680 RETURN




