30 DT1=43090:DT2=43091:DT3=43092:DT4=43093:DT5=42860:DT6=42861:DT7=42806:DT8=42807:DT9=42803:DT10=42804:DT11=42899:DT12=42998:DT13=42999
40 DT14=42836:DT15=42837:DT16=42833:DT17=42834:DT18=49812
50 ASM1=42800:ASM2=42830:ASM3=43000
60 ENV 1,15,-1,5:ENV 2,1,15,2,15,-1,3:ENV 3,8,1,6,3,1,6,1,0,100,8,-1,6,3,-1,6:MEMORY 29999:DIM EP%(100,4),EIM%(20,25,1),CO(15,1),SC%(100):N=ASM1:RESTORE 110
90 READ C$:IF C$="FIN"THEN 120
100 C=VAL("&"+C$):POKE N,C:N=N+1:GOTO 90
110 DATA 1E,8,1,0,0,21,0,0,16,4,7E,2,23,3,15,C2,3A,A7,D5,11,FC,7,19,D1,1D,C2,38,A7,C9,FIN
120 N=ASM2:RESTORE 150
130 READ C$:IF C$="FIN"THEN 160
140 C=VAL("&"+C$):POKE N,C:N=N+1:GOTO 130
150 DATA 1E,8,1,0,0,21,0,0,16,4,A,77,23,3,15,C2,58,A7,D5,11,FC,7,19,D1,1D,C2,56,A7,C9,FIN
160 FOR N=3 TO 15:INK N,N+10:NEXT
170 DATA 3E,0,32,52,A8,32,53,A8,2A,55,A8,E5,1,28,0,9,C1,1E,8,16,4,A,BE,C0,23,3,15,20,F8,D5,11,FC,7,19,E5,C5,E1,19,E5,C1,E1,D1,1D,20,E6,3E,1,32,52,A8,21,94,A7,3A,54,A8,FE,0,28,4,23,3D,20,FC,36,1,21,94,A7,6,64,3E,1,BE,C0,23,5,20,FA,32,53,A8,C9,FIN
180 RESTORE 170:N=ASM3
190 READ C$:IF C$="FIN"THEN 220
200 C=VAL("&"+C$):POKE N,C:N=N+1:GOTO 190
220 MODE 2:INK 1,20:BORDER 0:INK 0,0:LOCATE 25,6:PRINT"O P T I O N S":PRINT:PRINT:PRINT" * 1 - Instructions":PRINT:PRINT" * 2 - Sauvegarde dessins sur cassette":PRINT:PRINT" * 3 - Rappel dessins depuis la cassette":PRINT
260 PRINT" * 4 - Choix de la pallette de couleur":PRINT:PRINT" * 5 - Creation de nouveaux dessins (ou modifications)":PRINT:PRINT" * 6 - Visualisation des dessins en memoire":PRINT:PRINT" * 7 - Jeu de GOBPUZZLE"
300 A$=INKEY$:IF A$=""THEN 300
310 A=VAL(A$):IF A=0 OR A>7 THEN 300
320 ON A GOTO 4050,4250,4400,3600,340,4490,1830
340 GOTO 4640
350 MODE 2:PRINT"Desirez-vous rapeler un dessin en memoire (O/N)"
360 A$=UPPER$(INKEY$):IF A$=""THEN 360
370 IF A$="N"THEN 450
380 IF A$<>"O"THEN 220
390 CLS:PRINT"Quel numero ":INPUT N:IF N<1 OR N>4 THEN 390
400 DEP=30000+(N-1)*3200:AR=DT18:MODE 0:GOSUB 2990:GOTO 460
450 MODE 0
460 PEN 15:C=0:V=-1:VI=1:IND=1:CO=15:LOCATE 1,1:PRINT"IMP.RAPI":FOR N=0 TO 15:IF CO(N,1)=27 THEN 500
490 INK N,CO(N,0),CO(N,1):GOTO 510
500 INK N,CO(N,0)
510 NEXT:IF CO(15,0)<20 AND CO(15,1)<>27 THEN INK 15,24
520 FOR N=0 TO 15:PEN N:LOCATE N+1,3:PRINT HEX$(N):NEXT:X=160:Y=112:LOCATE 1,22:PEN 15:PRINT"COMdes:P-E-V-C-R-F"
560 B=TEST(X,Y):PT=0
580 A=JOY(0):PLOT X,Y,0:PLOT X,Y,15:FOR F=1 TO VI:NEXT:A$=UPPER$(INKEY$):IF A$=" "THEN GOSUB 800
600 IF A$="M"THEN 1260
610 IF A=0 THEN 580
620 PLOT X,Y,B:IF A>10 THEN PT=1:A=A-16
640 IF A=4 THEN X=X-4
650 IF A=8 THEN X=X+4
660 IF A=2 THEN Y=Y-2
670 IF A=1 THEN Y=Y+2
680 IF A=9 THEN X=X+4:Y=Y+2
690 IF A=10 THEN X=X+4:Y=Y-2
700 IF A=6 THEN X=X-4:Y=Y-2
710 IF A=5 THEN X=X-4:Y=Y+2
720 IF X<160 THEN X=160
730 IF X>476 THEN X=476
740 IF Y<112 THEN Y=112
750 IF Y>270 THEN Y=270
760 IF PT=0 THEN 560
770 PLOT X,Y,CO:GOTO 560
800 LOCATE 20,1:PRINT"*"
810 A$=UPPER$(INKEY$):IF A$=""THEN 810
820 IF A$="R"THEN GOSUB 1020
830 IF A$="E"THEN GOSUB 1430
840 IF A$="F"THEN GOSUB 1720
850 IF A$="V"THEN GOSUB 900
860 IF A$="C"THEN GOSUB 960
870 IF A$="P"THEN GOSUB 4000
880 LOCATE 20,1:PRINT" ":RETURN
900 V=NOT V:LOCATE 5,1:IF V=0 THEN VI=100:PRINT"LENT"
930 IF V=-1 THEN VI=1:PRINT"RAPI"
940 LOCATE 20,1:PRINT" ":RETURN
960 LOCATE 1,24:INPUT"COULEUR";CO$:IF CO$=""THEN 960
970 CO=VAL("&"+CO$):LOCATE 1,24:PRINT"           ":LOCATE 20,1:PRINT" ":RETURN
1020 PLOT X,Y,B:CF=B:LOCATE 1,23:PRINT"                  "
1040 LOCATE 1,23:INPUT"COULEUR BORDURE";CB$:IF CB$=""THEN 1040 ELSE CB=VAL("&"+CB$)
1050 LOCATE 1,24:INPUT"COULEUR REMPLI.";CR$:IF CR$=""THEN 1050 ELSE CR=VAL("&"+CR$)
1060 LOCATE 1,23:PRINT"                  ":LOCATE 1,24:PRINT"                  ":LOCATE 20,1:PRINT" ":XX=X:YY=Y:PLOT X,Y,CF:AX=X
1090 A$=INKEY$:IF A$=" "THEN 1240
1100 T=TEST(X,Y):IF T<>CF THEN 1140
1120 X=X-4:IF X>=160 THEN 1090
1130 X=X+4:GOTO 1190
1140 T=TEST(X,Y):IF T<>CB THEN 1120
1150 X=X+4:IF X>476 THEN 1240
1160 IF X>AX THEN 1170 ELSE 1180
1170 TT=TEST(X,Y+2):IF TT=CB THEN 1240
1180 T=TEST(X,Y):IF T=CB THEN 1150
1190 H=X
1200 T=TEST(H,Y):IF T=CF THEN PLOT H,Y,CR
1210 H=H+4:IF H>476 THEN 1230
1220 T=TEST(H,Y):IF T<>CB THEN 1200
1230 Y=Y-2:IF Y>=112 THEN AX=X:GOTO 1090
1240 Y=YY:X=XX:B=CR:PLOT X,Y,B:RETURN
1260 PLOT X,Y,B:LOCATE 1,1:INPUT"IMAGE No ";I$:IF I$=""THEN 1260 ELSE I=VAL(I$)
1270 IF I<1 OR I>4 THEN 1260
1280 ARR=(I-1)*3200+30000:FOR N=0 TO 9:FOR M=0 TO 9:DEP=DT18+M*4+N*80:HDEP=INT(DEP/256):LDEP=DEP-HDEP*256:HARR=INT(ARR/256):LARR=ARR-HARR*256:POKE DT7,LDEP:POKE DT8,HDEP:POKE DT9,LARR:POKE DT10,HARR
1370 CALL ASM1:ARR=ARR+32:NEXT M,N:FOR N=0 TO 15:POKE DT5+N*2,CO(N,0):POKE DT6+N*2,CO(N,1):NEXT:GOTO 220
1430 PLOT X,Y,B:CA=B
1440 LOCATE 1,24:INPUT"Nouvelle coul ";CN$:IF CN$=""THEN 1440 ELSE CN=VAL("&"+CN$)
1450 LOCATE 1,24:PRINT"                 ":XX=X:YY=Y
1470 A$=INKEY$:IF A$=" "THEN 1650
1480 PLOT X,Y,CN:X=X+4:GOSUB 1660:IF TEST(X,Y)=CA THEN 1470
1510 Y=Y+2:GOSUB 1660:IF TEST(X,Y)=CA THEN 1470
1530 X=X-4:GOSUB 1660:IF TEST(X,Y)=CA THEN 1470
1550 X=X-4:GOSUB 1660:IF TEST(X,Y)=CA THEN 1470
1570 Y=Y-2:GOSUB 1660:IF TEST(X,Y)=CA THEN 1470
1590 Y=Y-2:GOSUB 1660:IF TEST(X,Y)=CA THEN 1470
1610 X=X+4:GOSUB 1660:IF TEST(X,Y)=CA THEN 1470
1630 X=X+4:GOSUB 1660:IF TEST(X,Y)=CA THEN 1470
1650 X=XX:Y=YY:B=CN:PLOT X,Y,B:LOCATE 20,1:PRINT" ":RETURN
1660 IF X>476 THEN X=476
1670 IF X<160 THEN X=160
1680 IF Y>270 THEN Y=270
1690 IF Y<112 THEN Y=112
1700 RETURN
1720 PLOT X,Y,B:CA=B
1730 LOCATE 1,24:INPUT"Nouvelle coul.";CN$:IF CN$=""THEN 1730 ELSE CN=VAL("&"+CN$)
1740 LOCATE 1,24:PRINT"                 ":F=160
1760 T=112
1770 A$=INKEY$:IF A$=" "THEN 1810
1780 IF TEST(F,T)=CA THEN PLOT F,T,CN
1790 T=T+2:IF T<272 THEN 1770
1800 F=F+4:IF F<480 THEN 1760
1810 LOCATE 20,1:PRINT" ":B=CN:RETURN
1830 MODE 2:INK 1,24:INK 0,1:FOR N=1 TO 100:EP%(N,0)=0:SC%(N)=0:POKE DT11+N,0:NEXT:POKE DT12,1:POKE DT13,1:SC%(98)=1:SC%(99)=1:PB=0:FOR N=1 TO 20:FOR M=1 TO 25:EIM%(N,M,0)=0:EIM%(N,M,1)=0:NEXT M,N:INPUT"IMAGE ";I$
1870 IF I$=""THEN Z=3200*(INT(RND(1)*4))+30000:GOTO 1890
1880 Z=(VAL(I$)-1)*3200+30000
1890 PRINT:PRINT"Avec ou sans GOBPUZZLE (A/S)"
1900 A$=UPPER$(INKEY$):IF A$=""THEN 1900
1910 GOB=0:IF A$="A"THEN GOB=1
1920 FOR N=0 TO 15:IF CO(N,1)<27 THEN 1940
1930 INK N,CO(N,0):GOTO 1950
1940 INK N,CO(N,0),CO(N,1)
1950 NEXT:MODE 0:GOSUB 2980
1980 FOR N=1 TO 98
1990 L=INT(RND(1)*98)+1:IF EP%(L,0)<>0 THEN 1990
2010 EP%(L,0)=N:NEXT:EP%(99,0)=99:EP%(100,0)=100
2050 N=1:FOR Y=1 TO 15:IF INT(Y/2)=Y/2 THEN 2080 ELSE 2070
2070 FOR X=1 TO 13 STEP 2:GOSUB 2100:NEXT X:GOTO 2090
2080 FOR X=2 TO 12 STEP 2:GOSUB 2100:NEXT X
2090 NEXT Y:GOTO 2190
2100 EIM%(X,Y,0)=N:C=49152+(X-1)*4+(Y-1)*80:EP%(N,2)=INT(C/256):EP%(N,1)=C-EP%(N,2)*256
2130 C=(EP%(N,0)-1)*32+Z:EP%(N,4)=INT(C/256):EP%(N,3)=C-EP%(N,4)*256
2150 POKE DT14,EP%(N,1):POKE DT15,EP%(N,2):POKE DT16,EP%(N,3):POKE DT17,EP%(N,4):CALL ASM2:N=N+1:RETURN
2190 FOR N=0 TO 4 STEP 4:C=Z+3136+N*8:HDEP=INT(C/256):LDEP=C-HDEP*256:EP%(99+N/4,3)=LDEP:EP%(99+N/4,4)=HDEP:POKE DT16,LDEP:POKE DT17,HDEP:POKE DT14,160+N:POKE DT15,199:EP%(99+N/4,1)=160+N:EP%(99+N/4,2)=199
2250 CALL ASM2:NEXT:EIM%(9,25,0)=99:EIM%(10,25,0)=100:LOCATE 15,15:PEN 15:PRINT 0:CH=REMAIN(0):CH=REMAIN(1):EVERY 100,1 GOSUB 3110:IF GOB=0 THEN 2310 ELSE AFTER 500,0 GOSUB 3320
2310 SCORE=0
2330 IND=1:PEN 15:X=15:Y=10:DI:LOCATE X,Y:PRINT CHR$(159):EI
2350 A=JOY(0):IF INKEY(47)=0 THEN IND=1
2360 IF INKEY(60)=0 THEN A=REMAIN(0):A=REMAIN(1):GOTO 220
2370 IF INKEY(18)=0 THEN IND=IND+1
2380 IF A=0 THEN 2350
2390 IF A>16 THEN 2550
2400 EIM%(X,Y,1)=0:IF EIM%(X,Y,0)<>0 THEN 2430
2420 DI:LOCATE X,Y:PRINT" ":EI
2430 GOSUB 2810:IF EIM%(X,Y,0)<>0 THEN 2470
2450 DI:LOCATE X,Y:PRINT CHR$(159):EI:GOTO 2350
2470 N=EIM%(X,Y,0):DI:LOCATE X,Y:PRINT CHR$(159):EI
2490 IF JOY(0)=0 THEN 2490
2500 POKE DT16,EP%(N,3):POKE DT17,EP%(N,4):POKE DT14,EP%(N,1):POKE DT15,EP%(N,2):CALL ASM2:GOTO 2350
2550 IF EIM%(X,Y,0)=0 THEN A=A-16:GOTO 2420
2560 IF Y>15 THEN POKE DT11+(Y-16)*10+X,0
2570 AV=EIM%(X,Y,0):DI:LOCATE X,Y:PRINT" ":EI:EIM%(X,Y,0)=0
2580 A=A-16:GOSUB 2810:N=EIM%(X,Y,0):C=(X-1)*4+(Y-1)*80+49152:HARR=INT(C/256):LARR=C-256*HARR:POKE DT14,LARR:POKE DT15,HARR:POKE DT16,EP%(AV,3):POKE DT17,EP%(AV,4):CALL ASM2:EIM%(X,Y,0)=AV
2660 EP%(AV,1)=LARR:EP%(AV,2)=HARR
2670 A=JOY(0):IF INKEY(47)=0 THEN IND=1
2680 IF INKEY(18)=0 THEN IND=IND+1
2690 IF A=0 OR A=16 THEN 2670
2700 IF A<16 AND N=0 THEN 2790
2710 IF A<16 AND N<>0 THEN 2670
2720 IF N<>0 THEN 2740
2730 DI:LOCATE X,Y:PRINT" ":EI:EIM%(X,Y,0)=0:GOTO 2580
2740 POKE DT14,LARR:POKE DT15,HARR:POKE DT16,EP%(N,3):POKE DT17,EP%(N,4):CALL ASM2:EIM%(X,Y,0)=N:GOTO 2580
2790 IF Y>15 THEN GOSUB 3140:IF PEEK(DT2)=1 THEN 3200
2800 GOTO 2430
2810 DI:IF A=1 THEN Y=Y-1
2820 IF A=2 THEN Y=Y+1
2830 IF A=4 THEN X=X-1
2840 IF A=8 THEN X=X+1
2850 IF A=5 THEN Y=Y-1:X=X-1
2860 IF A=9 THEN Y=Y-1:X=X+1
2870 IF A=6 THEN Y=Y+1:X=X-1
2880 IF A=10 THEN Y=Y+1:X=X+1
2890 IF X>20 THEN X=20
2900 IF X<1 THEN X=1
2910 IF Y>25 THEN Y=25
2920 IF Y<1 THEN Y=1
2930 IF X>10 AND Y>15 THEN X=10:Y=15
2940 IF X=HO AND Y=VE THEN GOSUB 3530
2950 :FOR R=1 TO IND:NEXT:EI:RETURN
2980 DEP=Z:AR=50392
2990 FOR N=0 TO 9:FOR M=0 TO 9:ARR=AR+M*4+N*80:HDEP=INT(DEP/256):LDEP=DEP-256*HDEP:HARR=INT(ARR/256):LARR=ARR-HARR*256:POKE DT14,LARR:POKE DT15,HARR:POKE DT16,LDEP:POKE DT17,HDEP:CALL ASM2:DEP=DEP+32
3080 NEXT M,N:RETURN
3110 SCORE=SCORE-1:IF SCORE<0 THEN SCORE=0
3120 DI:LOCATE 15,15:PRINT SCORE:EI:RETURN
3140 POKE DT4,LARR:POKE 43094,HARR:U=(X-1)+10*(Y-16):POKE DT3,U:CALL ASM3:IF PEEK(DT1)=1 THEN SOUND 132,120,20,7:IF SC%(U)=0 THEN SCORE=SCORE+10:SC%(U)=1:PB=PB+1
3180 RETURN
3200 EI:A=REMAIN(0):A=REMAIN(1):DI:BORDER 0,9:SOUND 135,0,0:LOCATE 1,1:PRINT"PUZZLE COMPLET":LOCATE 15,15:PRINT"     ":LOCATE 1,3:PRINT"VOS POINTS:";SCORE:LOCATE 1,5:PRINT"UNE AUTRE PARTIE ?"
3260 A$=UPPER$(INKEY$):IF A$=""THEN 3260
3270 IF A$="N"THEN 220
3280 IF A$<>"O"THEN 3260
3290 BORDER 0:GOTO 1830
3320 SOUND 130,506,-32768,0,3,0,10:DI:HO=20:VE=1:LOCATE HO,VE:PRINT CHR$(225):CH=REMAIN(0):TP=INT(RND(TIME)*50)+30:EVERY TP,0 GOSUB 3400:EI:RETURN
3400 DI:LOCATE HO,VE:PRINT" ":IF HO<13 THEN 3430
3420 HO=HO-INT(RND(TIME)*3):VE=VE+INT(RND(TIME)*2):GOTO 3440
3430 HO=HO-5+INT(RND(TIME)*11):VE=VE-4+INT(RND(TIME)*9)
3440 IF HO<1 THEN HO=1
3450 IF HO>20 THEN HO=20
3460 IF VE<1 THEN VE=1
3470 IF VE>15 THEN VE=15
3480 LOCATE HO,VE:IF EIM%(HO,VE,0)<>0 AND EIM%(HO,VE,1)=0 THEN PRINT CHR$(224):SOUND 129,100,0,0,2:SCORE=SCORE-10:EIM%(HO,VE,1)=1:EI:RETURN
3500 PRINT CHR$(225):EI:RETURN
3530 CH=REMAIN(0):DI:LOCATE X,Y:PRINT" ":HO=0:VE=0:SOUND 131,0,0,0,1,0,5:TP=INT(RND(1)*(100-PB)*30)+50:AFTER TP,0 GOSUB 3320:EI:RETURN
3600 MODE 2:BORDER 0:INK 0,0:INK 1,20:PRINT"16 Chiffres numerotes de 0 a F vont apparaitre dans le haut de l'ecran":PRINT:PRINT"A l'aide des touches de direction,positionnez l'asterisque au dessous du chiffre":PRINT
3630 PRINT"puis appuyez sur la barre d'espace pour faire defiler les couleurs":PRINT:PRINT:PRINT"Si l'on desire 2 couleurs par stylo,appuyez sur ENTER pour avoir acces a la sec-onde couleur":PRINT
3650 PRINT"Au cours de la realisation du dessin,vous pouvez modifier les couleurs en ":PRINT"appuyant sur ESPACE  puis sur P (comme palette)":PRINT:PRINT:PRINT"A la fin de la selection,appuyez sur COPY":PRINT
3680 PRINT"          ------Appuyer sur M pour Menu,ESPACE pour continuer ------":GOSUB 3710:GOTO 220
3710 A$=UPPER$(INKEY$):IF A$=""THEN 3710
3720 IF A$="M"THEN RETURN
3730 MODE 0:PEN 15:INK 15,24:CO(15,0)=24:CO(15,1)=27:FOR N=0 TO 14:CO(N,0)=0:CO(N,1)=27:NEXT:FOR N=0 TO 15:LOCATE N+1,3:PRINT HEX$(N):NEXT:N=1:M=0:Q=-1
3790 LOCATE N,4:PEN 15:PRINT"*"
3800 A$=INKEY$:IF A$=""THEN 3800
3810 LOCATE N,4:PRINT" ":AS=ASC(A$):IF AS=224 THEN RETURN
3830 IF AS<>242 THEN 3860
3840 N=N-1:Q=-1:IF N<1 THEN N=1
3850 GOTO 3790
3860 IF AS<>243 THEN 3890
3870 N=N+1:Q=-1:IF N>16 THEN N=1
3880 GOTO 3790
3890 IF AS=13 THEN Q=NOT Q
3900 IF AS<>32 THEN 3790
3910 M=M+1:IF M>26 THEN M=0
3920 LOCATE 17,3:PEN 15:PRINT M;" ":INK N-1,M:LOCATE N,3:PEN N-1:PRINT HEX$(N-1):CO(N-1,1+Q)=M:IF Q=-1 THEN INK N-1,M:GOTO 3970
3960 INK N-1,CO(N-1,0),M
3970 PEN N-1:LOCATE N,3:PRINT HEX$(N-1):PEN 15:GOTO 3790
4000 N=CO+1:M=0:Q=-1:GOSUB 3790:LOCATE 20,1:PRINT" ":LOCATE 17,3:PRINT"   ":RETURN:END
4050 MODE 2:INK 1,20:INK 0,0:BORDER 0:PRINT:PRINT:PRINT"-A l'aide de la manette de jeux,vous devez reconstituer un puzzle...":PRINT:PRINT"Vous pouvez vous deplacer dans les 8 directions.Une croix marque votre position."
4080 PRINT"-En appuyant sur [FEU] vous ";CHR$(34);"emmenez";CHR$(34);" la piece avec vous.":PRINT:PRINT"-Une copie de l'image entiere apparait en bas a droite de l'ecran.":PRINT"-Vous devez reconstituer le puzzle a gauche de cette copie.":PRINT
4110 PRINT"-Si vous choisissez l'option avec GOBPUZZLE,un trouble fete vient de temps en   temps vous dissimuler les elements du puzzle  et vous faire perdre des points.":PRINT
4120 PRINT"-Repoussez le GOBPUZZLE a l'aide du Joystick,et faite reapparaitre la piece     cachee en passant simplement dessus.":PRINT
4130 PRINT"-L'ordinateur signale par un Bip sonore toute piece correctement placee et,     lorsque le puzzle est complet,arrete la partie.":PRINT
4140 PRINT"(En appuyant sur ENTER vous diminuer progressivement la vitesse de deplacement. Un appui sur ESPACE redonne la vitesse maximum)":PRINT:PRINT"               ----- Appuyer sur une touche -------"
4160 A$=INKEY$:IF A$=""THEN 4160
4170 CLS:PRINT:PRINT:PRINT"-Avant de lancer le jeu,il faut realiser des dessins qui seront ";CHR$(34);"eparpilles";CHR$(34):PRINT"par le programme.":PRINT
4180 PRINT"-Pour cela,un logiciel de dessin est inclu.Il contient diverses commandes pour  faciliter le trace.":PRINT:PRINT"-Ces dessins peuvent etre sauvegardes sur cassette et rappeles ulterieurements:"
4190 PRINT"                        (SAUVEGARDE et RAPPEL) ":PRINT:PRINT"         -  On peut memoriser jusqu'a 4 dessins. -":PRINT
4210 PRINT"-La palette de couleur devra etre choisie avant de commancer le dessin,et est   modifiable en cours de trace.Elle est commune aux 4 dessins.":PRINT:PRINT"            ------- Appuyez sur une touche --------------"
4230 A$=INKEY$:IF A$=""THEN 4230 ELSE 220
4250 MODE 2:PRINT"Donnez un nom aux dessins (eventuelement)":INPUT C$
4270 INPUT"Vitesse de sauvegarde (0/1)";V:IF V<0 OR V>1 THEN 4270
4290 SPEED WRITE V
4300 CLS:PRINT"Preparez le magnetophone,puis appuyez sur la barre d'espace":C$="!"+C$
4320 A$=INKEY$:IF A$=""THEN 4320
4330 IF A$<>" "THEN 220
4340 SAVE C$,B,30000,13000:CLS:PRINT"Une autre ? (O/N)"
4360 A$=UPPER$(INKEY$):IF A$=""THEN 4360
4370 IF A$="O"THEN 4300
4380 GOTO 220
4400 MODE 2:PRINT"Entrez le nom des dessins (eventuelement)":INPUT C$:C$="!"+C$:CLS:PRINT"Preparez le magnetophone puis appuyez sur la barre d'espace"
4430 A$=INKEY$:IF A$=""THEN 4430
4440 IF A$<>" "THEN 220
4450 LOAD C$,30000:FOR N=0 TO 15:CO(N,0)=PEEK(DT5+N*2):CO(N,1)=PEEK(DT6+N*2):NEXT:GOTO 220
4490 DATA 49152,49192,50352,50392
4500 RESTORE 4490:FOR N=0 TO 15:IF CO(N,1)=27 THEN 4530
4520 INK N,CO(N,0),CO(N,1):GOTO 4540
4530 INK N,CO(N,0)
4540 NEXT:MODE 0:FOR PTE=0 TO 3:DEP=30000+PTE*3200:READ AR:GOSUB 2990:NEXT PTE:PEN 15:LOCATE 5,11:PRINT"1":LOCATE 15,11:PRINT"2":LOCATE 5,15:PRINT"3":LOCATE 15,15:PRINT"4":LOCATE 1,13:PRINT"PRESSER UNE TOUCHE"
4620 A$=INKEY$:IF A$=""THEN 4620 ELSE 220
4640 MODE 2:INK 1,20:INK 0,0:BORDER 0:PRINT:PRINT:PRINT"-A l'aide de la manette de jeux,vous pouvez deplacer le curseur a":PRINT"l'interieur d'une fenetre de 80*80 points,et ceci dans 8 directions":PRINT
4670 PRINT"-Un appui sur la touche [ FEU ] laisse une trace.":PRINT:PRINT"-Pour avoir acces aux commandes,presser la barre d'ESPACE ":PRINT:PRINT"LISTE DES COMMANDES:":PRINT:PRINT"-V: ralenti ou accelere la vitesse de deplacement"
4710 PRINT"-P :permet de modifier la Palette de couleur":PRINT"-R :Rempli une surface fermee avec une couleur":PRINT"    (Positionner le curseur au plus haut de la surface)":PRINT:PRINT"-E :change la couleur d'un trait (Placer le curseur sur le trait)"
4750 PRINT"-C :permet de changer de stylo":PRINT"-F :affecte au Fond la couleur choisie. Placer le curseur sur la couleur a      remplacer (ancienne couleur de fond)":PRINT:PRINT"-Pour memoriser un dessin presser simplement M sans appuyer sur ESPACE"
4780 PRINT"                 (4 dessins peuvent-etre memorises)":PRINT:PRINT"           ----- Appuyez sur une touche -----"
4800 A$=INKEY$:IF A$=""THEN 4800
4810 CLS:PRINT:PRINT:PRINT"-Les commandes R,E,F peuvent etre interompue a tout moment par simple appui sur la barre d'espace":PRINT:PRINT" APPUYEZ SUR M POUR MENU,OU SUR LA BARRE D'ESPACE POUR CONTINUER"
4830 A$=UPPER$(INKEY$):IF A$=""THEN 4830
4840 IF A$="M"THEN 220 ELSE 350
