CODINGLISTINGS ★ 3D SHAPE ROTATOR ★

3D Shape RotatorCoding Listings
★ Ce texte vous est présenté dans sa version originale ★ 
 ★ This text is presented to you in its original version ★ 
 ★ Este texto se presenta en su versión original ★ 
 ★ Dieser Text wird in seiner Originalfassung präsentiert ★ 

As the title suggests, this listing from Simon Watson in Cornwall will rotate three-dimensional shapes. You must enter the number of sides the shape is to have. The program will draw it and then proceed to rotate it.

Once rotation has started, these keys will affect the shape: Fast, Medium, Slow rotation speed; Direction change; Ink colour; Reveal all 15 frames of animation.

1 ' 3D shape rotator
2 ' by Simon Watson
3 ' Amstrad Action   April 87
10 BORDER 0:INK 1,26:INK 0,0:BORDER 0:PEN 1:MODE 2
20 INPUT"Number of sides (5-10 works best)";side%:side%=side%-2
30 DIM col%(15):FOR n%=1 TO 15:READ col%(n%):NEXT
40 DATA 26,6,3,15,12,10,21,22,11,1,4,7,5,16,13
50 ' draw out all 15 frames
60 MODE 0:FOR a%=1 TO 2
70 IF a%=1 THEN ORIGIN 200,200 ELSE ORIGIN 440,200
80 FOR b%=1 TO 15:INK b%,0:c=b%*PI*2/(side%*15)
90 MOVE 150*COS(c),150*SIN(c)
100 FOR d%=1 TO side%:e=d%*2*PI/side%
110 DRAW 150*COS(e+c),150*SIN(e+c),b%
120 IF a%=1 THEN DRAWR 240,0:DRAWR -240,0
130 NEXT:NEXT:NEXT:f%=0:dir%=1:i%=7:rate%=50
140 ' rotate shape
150 f%=f%+dir%
160 IF f%=0 THEN f%=15
170 IF f%=16 THEN f%=1
180 IF i%=16 THEN i%=1
190 INK f%,col%(i%):i$=UPPER$(INKEY$):FOR delay%=1 TO rate%:NEXT
200 IF i$="F" THEN rate%=10
210 IF i$="M" THEN rate%=50
220 IF i$="S" THEN rate%=100
230 IF i$="D" THEN dir%=-dir%
240 IF i$="I" THEN i%=i%+1
250 IF i$="R" THEN FOR n%=1 TO 15:INK n%,i%:NEXT
260 INK f%,0:GOTO 150

★ PUBLISHER: Amstrad Computer User
★ YEAR: 1987
★ AUTHOR: Simon Watson

CPCrulez[Content Management System] v8.7-desktop
Page créée en 029 millisecondes et consultée 267 fois

L'Amstrad CPC est une machine 8 bits à base d'un Z80 à 4MHz. Le premier de la gamme fut le CPC 464 en 1984, équipé d'un lecteur de cassettes intégré il se plaçait en concurrent  du Commodore C64 beaucoup plus compliqué à utiliser et plus cher. Ce fut un réel succès et sorti cette même années le CPC 664 équipé d'un lecteur de disquettes trois pouces intégré. Sa vie fut de courte durée puisqu'en 1985 il fut remplacé par le CPC 6128 qui était plus compact, plus soigné et surtout qui avait 128Ko de RAM au lieu de 64Ko.