ORG &80
   RUN $

;; Quick & Dirty init
   ld hl,&c9fb
   ld (&38),hl   ; setup a dummy ISR
   im 1      ; switch to IM1
   ei      ; enable interrupts
   ld sp,$+3   ; setup stack pointer here

   ; rough CRTC init (will nuke monitor's sync!)
   ld hl,_data_crtc_context
   ld bc,&BDBE
_init_crtc
   bit 7,(hl)
   ex af,af'
   outi
   ld b,c
   outi
   ex af,af'
   jr z,_init_crtc
   ; wait until the monitor comes back to life
_halt   halt
   djnz _halt

;; 50 Hz main loop sustaining the multimode
main   ; wait for VSync
   ld b,&F5
   in a,(c)
   rra
   jr nc,main+2
   ; skip over the VBI
   djnz $
   ; wait for INT0
   halt
   ; entering timing critical part
   ; no interrupt allowed
   di
   ; synchronize precisely the CPU with the CRTC
   ld b,9
   djnz $
   nop
   ; initialize loop variables
   ld hl,&0600+200
   ld de,&8d8e
   ; pre-select CRTC.R3
   ld bc,&bc03
   out (c),c
   inc b

;;Loop timing structure (no to scale):
;;HCC: 54    64/0            12              36             50
;;Ops: [R3=2, R2=12, MODE 1] [MODE 2, R2=36] [R2=50, R3=6]  [loop]
;;
;;with R# referring to CRTC registers
;;
;;Notes:
;; An HSync of at least 2us is required to give the Gate Array enough time to switch screen mode
;; An HSync lasting less than 3us won't pass through the GA hence to the monitor

   ;enter the loop at @HCC=54
_loop_multimode
   dec c
   out (c),c   ; CRTC.R3 = 2
   dec b
   out (c),c   ; select CRTC.R2
   inc b
   ld a,12
   out (c),a   ; CRTC.R2 = 12 (to trigger an HSync at HCC=12)

   ld b,&7F
   out (c),d   ; select mid-res (MODE 1)
   ;@HCC = 12
   out (c),e   ; select hi-res (MODE 2)

   ld b,&bd
   ld a,12+24
   out (c),a   ; CRTC.R2 = 36 (to trigger an HSync at HCC=36)

   ; wasting CPU cycles to keep in sync with the CRTC
   DS 36-12 - 14 -2,0   

   ld a,50
   ;@HCC = 36
   out (c),a   ; CRTC.R2 = 50 (to trigger an HSync at HCC=50)
   dec b
   inc c
   out (c),c   ; select CRTC.R3
   inc b
   out (c),h   ; CRTC.R3 = 6
   ;@HCC <= 50
   ; loop
   dec l
   jr nz,_loop_multimode

   ei
   jp main

_data_crtc_context
   DB 0,63
   DB 1,48
   DB 2,50
   DB 3,&8e
   DB 4,38
   DB 5,0
   DB 6,30
   DB 7,35
   DB 8,0
   DB 9,7
   DB 12,&2c
   DB 13+128,&00