CODINGSOURCES ★ Scroling 16 pixels Overscan par TWO MAG pour l'Echo des Crocos ★

Scrolling 16 pixels en overscan|TWO-MAG)Coding Sources

 

;
;(C) TWO-MAG et l'Echo des Crocos 90
;
        ORG &9000               ; Ou aileurs si ca vous chante
        LD BC,&BC01             ; Ecran en overscan
        OUT (C),C
        LD BC,&BD32
        OUT (C),C
        LD BC,&BC02
        OUT (C),C
        LD BC,&BD31             ; ou 33 selon le CPC
        OUT (C),C
        LD BC,&BC07
        OUT (C),C
        LD BC,&BD17
        OUT (C),C
        LD BC,&BC06
        OUT (C),C
        LD BC,&BD15
        OUT (C),C
        XOR A
        CALL &BC0E              ; MODE 0
        LD HL,MESSAGE
        LD (PILE),HL
        LD A,3
        LD (PILE1),A
BOUCLE: CALL &BD19                   ; Balayage écran
        CALL SCROLL
        LD A,47                      ; Test touche 47 ( espace )
        CALL &BB1E
        JR Z,BOUCLE
        LD BC,&BC01                  ; Oui , on remet l'écran
        OUT (C),C                    ; Normal
        LD  BC,&BD28
        OUT (C),C
        LD BC,&BC02
        OUT (C),C
        LD  BC,&BD2E
        OUT (C),C
        LD BC,&BC07
        OUT (C),C
        LD  BC,&BD1E
        OUT (C),C
        LD BC,&BC06
        OUT (C),C
        LD  BC,&BD19
        OUT (C),C
        RET                          ; C'EST FINI
SCROLL: LD A,(PILE1)
        INC A
        AND 3
        LD (PILE1),A
        JR NZ,ECRAN
        LD HL,(PILE)
        LD A,(HL)
        INC HL
        OR A   ; SI 0 on boucle
        JR NZ,AFFICH
        LD HL,MESSAGE
        LD A,(HL)
        INC HL
AFFICH: LD (PILE),HL   ;  On affiche
        CALL &BBA5
        LD DE,&A000
        LD (PILE2),DE
        CALL &BC53
ECRAN:  LD HL,&C640
        LD DE,(PILE2)
        INC DE
        LD (PILE2),DE
        DEC DE
        LD BC,&308
DEPLACE: PUSH BC
DEPLACE1: LD A,(DE)
          AND &C0
          PUSH DE
          PUSH BC
          PUSH HL
          LD E,L
          LD D,H
          INC HL
          LD BC,&5E
          LDIR
          LD (DE),A
          POP HL
          POP BC
          LD A,H
          ADD A,8
          LD H,A
          JR NC,FRAME
          LD DE,&C064
          ADD HL,DE
FRAME:    POP DE
          DJNZ DEPLACE1
          INC DE     ; TIENS 16 DE HAUT
          INC DE
          INC DE
          INC DE
          POP BC
          DEC C
          JR NZ,DEPLACE
          RET
PILE      DEFB 2,0
PILE1     DEFB 1,0
PILE2     DEFB 5,0
MESSAGE   DB "UN P'TI SCROLL"
          DB "ET EN OVERSCAN EN PLUS"
          DB ", SYMPA NON ????"
          DB "                   "
          DB "LISEZ L'ECHO DES CROCOS!"
          DB " ET CA BOUCLE ...",&00

★ LICENCE: FREEWARE
★ ANNÉE: 1990
★ AUTEUR: TWO-MAG

★ AMSTRAD CPC ★ DOWNLOAD ★

Other platform tool:
» scrollOverscanTwoMagDATE: 2013-08-28
DL: 150 fois
TYPE: text
SIZE: 2Ko

Je participe au site:
» Newfile(s) upload/Envoye de fichier(s)
★ AMSTRAD CPC ★ A voir aussi sur CPCrulez , les sujets suivants pourront vous intéresser...

Lien(s):
» Coding Src's » Rsx - Fade Mix (Popular Computing Weekly)
» Coding Src's » Formatteur pour Amstrad CPC sous CP/M v2.2 (CPC Revue)
» Coding Src's » Dump de Secteurs de Disquette (Amstrad Magazine)
» Coding Src's » RSX BOX (Amstrad Computer User)
» Coding Src's » Indextablelle (CPC Amstrad International)
» Coding Src's » Banner Print For Epson (Amstrad Computer User)

CPCrulez[Content Management System] v8.75-desktop/c
Page créée en 084 millisecondes et consultée 1013 fois

L'Amstrad CPC est une machine 8 bits à base d'un Z80 à 4MHz. Le premier de la gamme fut le CPC 464 en 1984, équipé d'un lecteur de cassettes intégré il se plaçait en concurrent  du Commodore C64 beaucoup plus compliqué à utiliser et plus cher. Ce fut un réel succès et sorti cette même années le CPC 664 équipé d'un lecteur de disquettes trois pouces intégré. Sa vie fut de courte durée puisqu'en 1985 il fut remplacé par le CPC 6128 qui était plus compact, plus soigné et surtout qui avait 128Ko de RAM au lieu de 64Ko.