CODINGSOURCES ★ Coding source &006 ★

Il n'exite biensur pas 365 couleurs sur CPC ... c'est tout simplement le raprochement de 2 pixels de couleurs différente qui rends cela possible.

 

;
; Routine de defilement de 365 couleurs (mode 2)
; (c) 90 Benjy pour N.D.C No 3
;
; Ca sert a rien mais c'est tres bO
;
         ORG  #a000                     ;Call &a000
         ENT  #a000
;
         LD   bc,0
         CALL #bc38                     ;border 0
         LD   a,2
         CALL #bc0e                     ;mode 2
         LD   hl,#c000
         LD   de,#c001
         LD   bc,#3fff                  ;rempli écran d'une trame cadrillee
         LD   (hl),#aa
         LDIR
;
; les 9 lignes precedentes sont facultatives dans le cas ou vous
; voulez essayer en mode 1
;
         DI                             ;stop interruptions
         LD   hl,(#39)                  ;detourne le RST #38
         LD   (phl+1),hl
         LD   hl,inter
         LD   (#39),hl
         EI                             ;ok interruption
;
wloop    EI
         HALT                           ;attend prochaine interrupt
         CALL #bb1b                     ;touche pressee ?
         JR   nc,wloop
;
         DI                             ;si oui, c'est la fin des haricots
         LD   hl,(phl+1)
         LD   (#39),hl
         EI
         RET                            ;bye ! Passe le bonjour a ta mere
;
inter    DI
         LD   b,#f5                     ;ou k'en est l'balayage ?
         IN   a,(c)
         RRA
         RET  nc                        ;s'il reste de la poussiere, attend.
;
         LD   hl,309                    ;attend un peu j'ai une envie pressante
tempo    DEC  hl
         LD   a,h
         OR   l                         ;ou sont les water ?
         JR   nz,tempo
         NOP
         NOP
;
         LD   ix,inks                   ;ix pointe son doigt muscle
         LD   hl,(depink)               ;sur les couleurs
         LD   b,0
;
iloop    LD   a,h                       ;on se passe de commentaire
         LD   (code+2),a
         LD   a,l
         LD   (code2+2),a
;
         PUSH bc
         LD   bc,#7f00
code     LD   a,(ix+0)
         OUT  (c),c
         OUT  (c),a                     ;envoie couleur Dadiou !
code2    LD   a,(ix+0)
         INC  c
         OUT  (c),c
         OUT  (c),a                     ;Encore !!!
         INC  l
         BIT  5,l
         RES  5,l
         JP   z,suite
         INC  h
         RES  5,h
         POP  bc
         NOP
         NOP
         DJNZ iloop
         JP   suite2
;
suite    INC  a
         RES  5,h
         POP  bc
         NOP
         NOP
         DJNZ iloop
;
suite2   LD   hl,(depink)
         INC  l
         BIT  5,l
         RES  5,l
         JR   z,fin
         INC  h
         RES  5,h
fin      LD   (depink),hl
         EI
phl      JP   #b941                     ;fin detournement, fait comme si.
;
depink   DEFW 0
;
; a vous de mettre vos couleurs
;
inks     DEFB #44,#55,#57,#53           ;bleu
         DEFB #57,#55,#44
         DEFB #5c,#4c,#4e,#4b,#4e,#4c   ;rouge
         DEFB #5c
         DEFB #58,#45,#4d,#4f           ;violet
         DEFB #4d,#45,#58
         DEFB #4c,#4e,#4a,#4b           ;jaune
         DEFB #4a,#4e,#4c
         DEFS 10,#44                    ;Fin de table

Fanzine : Noix de Croco n°3 par Duffy

★ LICENCE: FREEWARE
★ ANNÉE: 1990
★ AUTEUR: BENJY

★ AMSTRAD CPC ★ DOWNLOAD ★

Other platform tool:
» NDC3  365cDATE: 2013-08-28
DL: 128 fois
TYPE: text
SIZE: 3Ko

Je participe au site:
» Newfile(s) upload/Envoye de fichier(s)
★ AMSTRAD CPC ★ A voir aussi sur CPCrulez , les sujets suivants pourront vous intéresser...

Lien(s):
» Coding Src's » Teletext Aid (Popular Computing Weekly)
» Coding Src's » Rasters en overscan
» Coding » Menu - Sources
» Coding Src's » Rsx - Programme zum Erstellen von Befehlen für Den CPC 464 (CPC Amstrad International)
» Coding Src's » Rsx - Programm - Tracer (CPC Amstrad International)
» Coding Src's » X-Treme discmag (Soucepack by Prodatron)

CPCrulez[Content Management System] v8.75-desktop/c
Page créée en 054 millisecondes et consultée 875 fois

L'Amstrad CPC est une machine 8 bits à base d'un Z80 à 4MHz. Le premier de la gamme fut le CPC 464 en 1984, équipé d'un lecteur de cassettes intégré il se plaçait en concurrent  du Commodore C64 beaucoup plus compliqué à utiliser et plus cher. Ce fut un réel succès et sorti cette même années le CPC 664 équipé d'un lecteur de disquettes trois pouces intégré. Sa vie fut de courte durée puisqu'en 1985 il fut remplacé par le CPC 6128 qui était plus compact, plus soigné et surtout qui avait 128Ko de RAM au lieu de 64Ko.